Delphi2005以上では、HTMLHelpがデフォルトになっています。そのため、 WinHelpを呼び出すには、USES節にWinHelpViewerを追加する必要があります。但し、 Forms.pasにバグがあるため、始めにそれを修正しなくてはなりません。ここではその手順を 示します。

unit Unit1;

interface

uses
  Windows, SysUtils, Classes, Controls, Forms, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

// hhctrl.ocxからHtmlHelpAを静的にリンク
function HtmlHelpA(hwndCaller:Integer;		// ウィンドウのハンドル
                   pszFile:PChar;		// ヘルプファイルの文字列のポインタ
                   uCommand:Integer;		// アクション
                   dwData:Integer		// マップ番号、トピックのポインタなど
		   ):Integer;stdcall;external 'hhctrl.ocx';

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
HtmlHelpA(Handle, PChar('help.chm'), 1, 0);	// uCommandの1はHH_DISPLAY_TOC（目次を表示）
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
HtmlHelpA(0, nil, 18, 0);		// uCommandの0はHH_CLOSE_ALL
end;					// この場合、他の引数に0,nilを渡す

end.

上の例では、HtmlHelpA APIを使うためにhhctrl.ocxを静的にリンクしています。 静的リンクでは、アプリケーション起動時にhhctrl.ocxをリンクすることになります。 無事にリンクされた後は、HtmlHelpA関数をDelphiで定義された関数 として使用することができます。

HtmlHelpA関数は、第一引数（hwndCaller）にウィンドウのハンドルを、 第二引数（pszFile）にヘルプファイル文字列のポインタ（PChar）を渡します。 第三引数（uCommand）はヘルプのアクションを整数で指定します （アクションはこちらを参照）。 第四引数（dwData）にはマップファイルの整数や、キーワードをPCharとDWORDでキャストした整数が入ります。

上の例では静的にリンクしました。万が一、アプリケーション起動時にhhctrl.ocxが 見つからない場合、起動できなくなります。それを避けるには動的にリンクします。 具体的なコードは下のようになります。

unit Unit1;

interface

uses
  Windows, SysUtils, Classes, Controls, Forms, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private 宣言 }
    HTMLDLL : THandle;	// DLLをロードする際のハンドル
  public
    { Public 宣言 }
  end;

type		// THtmlHelp型を定義
    THtmlHelp = function (hwndCaller:Integer;
			  pszFile:PChar;
                          uCommand:Integer;
			  dwData:Integer
                         ):Integer;stdcall;
var
  Form1: TForm1;
  HtmlHelp : THtmlHelp;		// HtmlHelpをグローバル変数で宣言

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
HTMLDLL := 0;		// ハンドルを初期化
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
if HTMLDLL = 0 then
    begin
    HTMLDLL := LoadLibrary('hhctrl.ocx');	// hhctrl.ocxをロード
    HtmlHelp := THtmlHelp(GetProcAddress(HTMLDLL,'HtmlHelpA'));
    end;
if @HtmlHelp <> nil then
    HtmlHelp(Handle, PChar('help.chm'), $0001, 0);	// 目次を表示してヘルプを起動
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
if @HtmlHelp <> nil then
  begin
  HtmlHelp(0, nil, 18, 0);	// HTMLHelpファイルを閉じる
  FreeLibrary(HTMLDLL);		// ハンドルを解放
  end;
end;

end.

上の例では、Button1をクリックした際にhhctrl.ocxを動的にリンクするようにしています。 もし、Button1Click以外の関数でもHtmlHelp関数を使う場合は、OnCreateイベント中で hhctrl.ocxをリンクすると良いと思います。